Нахождение длины дуги эллипса

Задача нахождения длины дуги эллипса носит все же некий теоретический характер, ибо практического применения, честно говоря, не вижу. Безусловно, посчитать путь от полюса до экватора — это важно, но ни в одном из проектов мне это не понадобилось.

Скачать исходник + исполняемый файл

Для построения профессиональной графики совсем не надо считать длину дуги, потому что существующий инструментарий все делает за вас, используя более очевидные входные данные.

Однако, мне стало интересно практическое плечо этого рычага на весах здравого смысла, а именно наиболее оптимальный метод, совмещающий в себе быстроту выполнения, ясный алгоритм и точность результата.

Для нахождения длины дуги эллипса нет какой-то определенной функции, как в случае длины дуги окружности, или нахождения координат точки на эллипсе. Это интегральное уравнение. Которое надо решать как обычно делается в подобных случаях: суммировать очень маленькие значения, которые получаются в результате работы некоей функции, на заданном диапазоне данных, которые наращиваются на чрезвычайно малую постоянную величину. Эта малая величина задается вызывающей стороной. Может быть применен некий алгоритм для определения «малости». На подобных алгоритмах останавливаться в этой статье не буду, ибо получится много и скучно. В конце статьи есть рабочий пример с исходниками, в котором можно поиграться с этой «малостью».

Длина дуги, как сумма хорд

Самое простое, что может прийти в голову, это двигаться от начала дуги к ее концу с небольшим наращиванием угла отклонения, считать хорду и прибавлять ее к накапливаемой сумме.

Рис.1. Сумма хорд

Формула такова:

(1) Сумма хорд

Проще говоря, находим координаты двух точек на эллипсе, отстоящих друг от друга на некий малый угол, по ним находим хорду, как гипотенузу получившегося прямоугольного треугольника.

В коде выглядит так:

//*****************************************************************
//  Нахождение длины дуги эллипса, заданного прямоугольником ARect
//  По аналогии с GDI+, углы в градусах, по часовой. Хордами
//  ∑ √ (Δx² + Δy²)
//*****************************************************************
function CalcArcEllipseLen1(ARect : TxRect;        // эллипс
                            startAngle : Extended; // старт.угол
                            sweepAngle : Extended; // угол дуги 
                            deltaAngle : Extended=0.01 // дискрета  
                            ): Extended;
var tmp : Extended; // наращиваемый угол
    pnt : TxPoint;  // новые координаты по tmp
    val : TxPoint;  // координаты в предыдущей итерации 
    dw : Extended;  // убывающий параметр цикла
    l : extended;   // длина текущей хорды
begin
//-- переводим градусы в радианы --------------------------------
  startAngle := startAngle * pi/180;
  sweepAngle := sweepAngle * pi/180;
  deltaAngle := deltaAngle * pi/180;
//-- инициализируем ---------------------------------------------  
  tmp := startAngle;
  dw := sweepAngle;
  result := 0;      
//-- стартовая координата ---------------------------------------
  val := CalcEllipsePointCoord(ARect,tmp);
  repeat
    //-- уменьшаем параметр цикла ---------------- 
    dw := dw - deltaAngle;
    //-- определяем значение угла ----------------
    if dw < 0 then tmp := tmp + (deltaAngle+dw)
    else tmp := tmp + deltaAngle;         
    //-- считаем новую точку на эллипсе ----------
    pnt := CalcEllipsePointCoord(ARect,tmp);
    //-- длина хорды -----------------------------
    l := sqrt(sqr(val.X-pnt.x)+sqr(val.Y-pnt.y));
    //-- сумма, интеграл -------------------------
    result := result+l;
    val := pnt;    
  until dw < 0;
end;

Проверим с планетарным размахом. По последним данным Международной Службы Вращения Земли (IERS — 1996) большая экваториальная полуось Земли равна 6 378 136,49 м, а полярная малая — 6 356 751,75 м.

Посчитаем периметр меридиана каким-нибудь онлайн-калькулятором, получаем 40 007 859.543 (некоторые могут дать другое число, т.к. используют приближенные формулы для вычисления периметра).

Представленная выше функция за 109 милисекунд выдала результат 40 007 996.265 при дельте 0.001. Это нельзя назвать точным результатом.

Длина дуги, как интеграл

Длиной некоторой дуги называется тот предел, к которому стремится длина вписанной ломаной, когда длина наибольшего ее звена стремится к нулю:

(2) Предел суммы хорд при максимальной длине хорды, стремящейся к нулю
(3) Длина t-го звена (хорды) вписанной ломаной

Таким образом, длина дуги эллипса может быть описана интегральным уравнением:

(4) Интегрально-дифференциальное уравнение дуги эллипса

Используя параметрическое уравнение эллипса, приходим к уравнению:

Где t1 и t2 – параметры для начала и конца дуги параметрического уравнения эллипса. Параметром является некий угол к оси абсцисс. Что такое и как найти параметр для угла эллипса подробно изложено тут.

Зная, что (cos t)’ = — sin t, (sin t)’ = cos t (подробный вывод приведен тут и тут), получаем следующую формулу:

(5) Длина дуги эллипса

Выводов достаточно, чтобы написать вторую функцию нахождения длины дуги эллипса.

//*****************************************************************
//  Нахождение длины дуги эллипса, заданного через a и b  
//  Сумма от корня суммы квадратов производных, через sin/cos по ∂t
//  ∑ [√(∂x²/∂t² + ∂y²/∂t²)] ∂t
//*****************************************************************
function CalcArcEllipseLen2(a,b : extended;        // полуоси
                            startAngle : Extended; // старт.угол
                            sweepAngle : Extended; // угол откл.
                            deltaAngle : Extended=0.01 // дискрета
                            ): Extended; 
var sn,cs: Extended;// синус, косинус
    tmp : Extended; // наращиваемый угол
    bet : Extended; // старый параметр
    dw : Extended;  // убывающий параметр цикла
    t : Extended;   // новый параметр
    l : extended;   // значение функции в t
begin
//-- переводим градусы в радианы --------------------------------
  startAngle := startAngle * pi/180;
  sweepAngle := sweepAngle * pi/180;
  deltaAngle := deltaAngle * pi/180;
//-- инициализируем ---------------------------------------------    
  tmp := startAngle;
  dw := sweepAngle;
  result := 0; 
//-- параметр для начального угла -------------------------------
  SinCos(tmp,sn,cs);
  bet := ArcTan2(a*sn, b*cs);
      
  repeat
    //-- уменьшаем параметр цикла ---------------- 
    dw := dw - deltaAngle;
    //-- определяем значение угла ----------------    
    if dw < 0 then 
      tmp := tmp + (deltaAngle+dw)
    else tmp := tmp + deltaAngle;         
    //-- находим параметр для угла ---------------
    SinCos(tmp,sn,cs);
    t := ArcTan2(a*sn, b*cs);
    //-- разница между параметрами dt=t-bet ------
    bet := CalcSweepAngle(bet,t);
    //-- эллиптический интеграл II рода ----------
    SinCos(t,sn,cs);
    l := sqrt ( sqr(a)*sqr(sn) + sqr(b)*sqr(cs))*bet;
    //-- запоминаем параметр ---------------------
    bet := t;
    //-- сумма, интеграл -------------------------    
    result := result+l;
  until dw <= 0;
end;

Результат при dt = 0.001 равен 40 007 859,543 за 109 милисекунд. Отлично!

Длина дуги через эксцентриситет

Это еще не окончательный вид уравнения. В ряде интересных параметров для эллипса есть такая числовая характеристика, показывающая степень отклонения эллипса от окружности, как эксцентриситет. Формула для эллипса:

(6) Эксцентриситет эллипса через полуоси

Чем эксцентриситет ближе к нулю, т.е. разница между a и b меньше, тем больше эллипс похож на окружность и наоборот, чем эксцентриситет ближе к единице, тем он более вытянут.

Выразим b2 = a2 (1 — e2), подставим в формулу (5), помним, что sin2t + cos2t = 1 (справочник [1]), убираем a2 за знак корня, и, как постоянную величину, за знак интеграла тоже, получаем:

(7) Окончательный вид уравнения для длины дуги эллипса

Пишем функцию, ожидаем более шустрого выполнения:

//*****************************************************************
//  Нахождение длины дуги эллипса, заданного через a и b  
//  По аналогии с GDI+, углы в градусах, по часовой. Считаем E(t,e)
//  a ∑ [√(1-e²cos²t)] ∂t
//*****************************************************************
function CalcArcEllipseLen3(a,b : extended;        // полуоси
                            startAngle : Extended; // старт.угол
                            sweepAngle : Extended; // угол откл.
                            deltaAngle : Extended=0.01 // дискрета
                            ): Extended; 
var sn,cs: Extended;// синус, косинус
    tmp : Extended; // наращиваемый угол
    bet : Extended; // старый параметр
    dw : Extended;  // убывающий параметр цикла
    ex : Extended;  // эксцентриситет
    t : Extended;   // новый параметр
    l : extended;   // значение функции в t
begin
//-- переводим градусы в радианы --------------------------------
  startAngle := startAngle * pi/180;
  sweepAngle := sweepAngle * pi/180;
  deltaAngle := deltaAngle * pi/180;
//-- считаем эксцентриситет -------------------------------------  
  ex := 1 -sqr(b)/sqr(a);
//-- инициализируем ---------------------------------------------    
  tmp := startAngle;
  dw := sweepAngle;
  result := 0; 
//-- параметр для начального угла -------------------------------
  SinCos(tmp,sn,cs);
  bet := ArcTan2(a*sn, b*cs);
      
  repeat
    //-- уменьшаем параметр цикла ---------------- 
    dw := dw - deltaAngle;
    //-- определяем значение угла ----------------    
    if dw < 0 then 
      tmp := tmp + (deltaAngle+dw)
    else tmp := tmp + deltaAngle;         
    //-- находим параметр для угла ---------------
    SinCos(tmp,sn,cs);
    t := ArcTan2(a*sn, b*cs);
    //-- разница между параметрами dt=t-bet ------
    bet := CalcSweepAngle(bet,t);
    //-- эллиптический интеграл II рода ----------
    l := sqrt (1-ex*sqr(cos(t)))*bet;
    //-- запоминаем параметр ---------------------
    bet := t;
    //-- сумма, интеграл -------------------------    
    result := result+l;
  until dw <= 0;
  result := a*result;
end;

Результат 40 007 859.543, за чуть меньшее время, 94 милисекунды.

Длина дуги через эксцентриситет с подготовкой

Возьмем за основу последнюю функцию. Алгоритм построен так, что в цикле идем от стартового угла, к конечному, на каждой итерации подсчитывая параметр. А если сразу посчитать начальный и конечный параметры и определить условие выхода из цикла? Этим мы однозначно снизим вычислительную нагрузку внутри цикла.

Рис.2. Параметры дуги эллипса.

То есть, вместо того, чтобы идти из точки A в точку B, мы заранее считаем параметры t1 и t2. И в цикле больше нахождением параметров не занимаемся, а только считаем очередное приращение.

Берем код последней реализации и улучшаем:

//*****************************************************************
//  Нахождение длины дуги эллипса, заданного через a и b  
//  По аналогии с GDI+, углы в градусах, по часовой. Считаем E(t,e)
//  a ∑ [√(1-e²cos²t)] ∂t
//  Но параметры и угол отклонения параметра считаем заранее 
//*****************************************************************
function CalcArcEllipseLen4(a,b : extended;        // полуоси
                            startAngle : Extended; // старт.угол
                            sweepAngle : Extended; // угол откл.
                            deltaAngle : Extended=0.01 // дискрета
                            ): Extended; 
var sn,cs: Extended;// синус, косинус
    tmp : Extended; // наращиваемый угол
    bet : Extended; // старый параметр
    dw : Extended;  // убывающий параметр цикла
    ex : Extended;  // эксцентриситет
    l : extended;   // значение функции в t
begin
//-- переводим градусы в радианы --------------------------------
  startAngle := startAngle * pi/180;
  sweepAngle := sweepAngle * pi/180;
  deltaAngle := deltaAngle * pi/180;
//-- считаем эксцентриситет -------------------------------------  
  ex := 1 -sqr(b)/sqr(a);
//-- инициализируем ---------------------------------------------    
  tmp := startAngle;
  result := 0; 
//-- параметр для начального угла -------------------------------
  SinCos(tmp,sn,cs);
  bet := ArcTan2(a*sn, b*cs);
//-- считаем параметр для цикла ---------------------------------  
  SinCos(tmp+sweepAngle,sn,cs);  
  dw := ArcTan2(a*sn, b*cs);
  dw := CalcSweepAngle(bet, dw); 
//-- для корректной работы цикла, запоминаем в бет старт.параметр  
  tmp := bet;
//-- если sweepAngle = 360, результат будет равен 0 ------------- 
//-- если sweepAngle > 360, результат будет от оставшейся разницы 
  if sweepAngle >= 2*pi then 
    dw := 2*pi + dw;
  repeat
    //-- уменьшаем параметр цикла ---------------- 
    dw := dw - deltaAngle;
    bet := tmp;
    //-- определяем значение угла ----------------    
    if dw < 0 then tmp := tmp + (deltaAngle+dw)
    else tmp := tmp + deltaAngle;         
    //-- разница между параметрами dt=tmp-bet ----
    bet := CalcSweepAngle(bet,tmp);
    //-- эллиптический интеграл II рода ----------
    l := sqrt (1-ex*sqr(cos(tmp)))*bet;
    //-- сумма, интеграл -------------------------    
    result := result+l;
  until dw <= 0;
  result := a*result;
end;

Результат — 40 007 859,543 за 30 милисекунд! Мысль явно здравая.

Длина дуги и хорошо забытые хорды

Но вернемся к сумме хорд. Что там-то не так? Казалось бы, все просто, понятно и должно работать, но результат, мягко говоря, не точен.

Работая с вещественными типами, результат зависит от «мелкости» приращения, от разрядности используемых типов. Накапливаемые погрешности, неточное представление дробного числа и прочие прелести чисел с плавающей запятой.

Тип Extended – самый точный из существующих в Delphi (и, как следствие, самый медленный). Перепишем нахождение длины дуги хордами, используя этот тип, и без вызовов внешних функций нахождения координат на эллипсе.

//*****************************************************************
//  Нахождение длины дуги эллипса, заданного через a и b  
//  По аналогии с GDI+, углы в градусах, по часовой. Считаем хордами
//  Абсолютно то же самое, что (1), но типы и точность изменены
//  ∑ √ (Δx² + Δy²)
//*****************************************************************
function CalcArcEllipseLen5(a,b : extended;        // полуоси
                            startAngle : Extended; // старт.угол
                            sweepAngle : Extended; // угол откл.
                            deltaAngle : Extended=0.01 // дискрета
                            ): Extended; 
var sn,cs: Extended;// синус, косинус
    tmp : Extended; // наращиваемый угол
    dw : Extended;  // убывающий параметр цикла
    l : extended;   // длина текущей дуги
    vx,vy : extended;
    px,py : Extended;
begin
//-- переводим градусы в радианы --------------------------------
  startAngle := startAngle * pi/180;
  sweepAngle := sweepAngle * pi/180;
  deltaAngle := deltaAngle * pi/180;
//-- инициализируем ---------------------------------------------  
  tmp := startAngle;
  dw := sweepAngle;
  result := 0;      
//-- находим параметр (некий угол) для уравнения ---
  SinCos(tmp,sn,cs);
  SinCos (ArcTan2(a*sn, b*cs), sn, cs);
  vX := a * cs;
  vY := b * sn;
  repeat
    //-- уменьшаем параметр цикла ---------------- 
    dw := dw - deltaAngle;
    //-- определяем значение угла ----------------
    if dw < 0 then tmp := tmp + (deltaAngle+dw)
    else tmp := tmp + deltaAngle;         
    //-- считаем новую точку на эллипсе ----------
    SinCos(tmp,sn,cs);
    SinCos (ArcTan2(a*sn,b*cs),sn,cs);
    pX := a * cs;
    pY := b * sn;
    //-- длина хорды -----------------------------
    l := sqrt(sqr(pX-vx)+sqr(pY-vy));
    //-- сумма, интеграл -------------------------
    result := result+l;
    vx := px;    
    vy := py;        
  until dw < 0;
end; 

Результат 40 007 859.542 за 94 милисекунды. Разница в одну тысячную, и такое же время. Весьма неплохо!

Практика

Качаем, запускаем. Видим такое окно:

Рис.3. Пример: Вид при запуске

При запуске в полях полуосей находятся «земные» значения. Эллипс сильно смахивает на окружность. Можно сразу нажать «Расчет», увидеть значения полярного меридиана, и начинать уже эксперименты.

Для начала проверим корректность получаемых результатов. Я попытался найти какие-нибудь онлайн калькуляторы для подсчета длины дуги эллипса, в которых можно было бы указать стартовый угол и произвольное отклонение, либо просто пару углов, определяющих дугу. Но все калькуляторы считают периметр эллипса. А с произвольной дугой как-то… не встретились.

Картинка из вики:

Длина дуги эллипса (s) в зависимости от его параметра (θ) Автор: Illustr — собственная работа, CC BY-SA 4.0, Ссылка

Заскриним несколько моментов и посчитаем корректность:

Рис.4. Скрины расчетов

Введем a=2, b=0.5, стартовый угол равен 0, отклонение θ=5.642.

Рис.5. Подсчет длины дуги для a=2, b=0.5, стартовый угол=0, отклонение θ=5.642

Видим результат у всех один 8.055. Т.е правы все.

Аналогично поступаем с остальными тремя скринами:

  • отклонение θ=1.154. У нас получился результат 1.333. На скрине видим результат s=1.334. Как так? Давайте увеличим «Дельту» в 10 раз, т.е. вместо 0.001, сделаем 0,01. У всех интегральных 2) 3) 4) результат станет 1.334. В то время, как у 1) и 5), т.е. примитивно-неинтегрально-хордовых останется 1.333.

Какой результат более истинный? Смотрите сами. Уменьшение дельты, т.е. угла для подсчетов, ведет к более точному результату. На 0.001 интегральные функции выдали результат как хордовые. При более грубой дельте, интегральные чуть изменились, а хордовые верны своему результату.

Сделаем дельту очень мелкой, равной 0.00001. Результат у всех, кроме первой, тот же, 1.333.

Лично я начинаю верить 5-ой формуле.

  • отклонение θ= 206. У нас получился результат 4.322. На скрине результат s= 4.322. Дельта 0.001. Все отлично.
  • отклонение θ= 4,488. У нас получился результат 5,989. На скрине результат s= 5,989. Дельта 0.001. Все отлично.

Вывод : Формулы 2-5 работают как надо. Фаворит 5. За меньшее время, т.е. при более «грубой» дельте, находит правильный результат.

Проверим на ужасных эллипсах. Т.е. где эксцентриситет очень близок к единице.

Рис.6. Проверка на очень «сплющенном» эллипсе

Можем заметить следующее: при 0.00001 функции 2 и 3 дали результат, близкий к результату функции 4, полученный при дельте 0.001. При дельте 0.00001 функция 4 дала результат, близкий к результату функции 5. Сама же функция 5 слабо колеблется в показаниях, что при дельте в 0.001, что при 0.00001.

Аналогичную ситуацию можно пронаблюдать при сильно вытянутом эллипсе:

Рис.7. Проверка на очень «вытянутом» эллипсе

Таким образом, имеет смысл использовать функции 4 и 5. Одну, как представительницу интегрального сословия, самую быструю и более точную из них. Другую, как представительницу очевидного и простого метода, работающую, между тем, лучше своих интегральных коллег при минимальных ресурсных затратах.

По интерфейсу

Не использовано ничего стороннего. Все рисуется для этого проекта. К разговору о том, что не надо гоняться за какими-то компонентами и навсегда привязывать себя к ним. Вы в состоянии нарисовать любой интерфейс. Особенно полезно для заказов, где уже есть макет. Представьте, как приятно будет с легкой ленцой сказать – «Именно так? Да не вопрос!».

Правая кнопка мыши задает стартовый угол. Удерживая правую кнопку мыши можно «прогуляться» по эллипсу. Конечная точка дуги будет следовать за стартовой точкой, отстоя на заданный ранее угол. Если поставить галку на «сохранять параметрическое отклонение», параметрический угол между t1 и t2 станет неизменен. Очень полезно пронаблюдать, как будет меняться сектор.

Левая кнопка мыши задает конечную точку дуги, т.е. угол отклонения.

Для интересующихся GDI+, надеюсь, их стало больше к этому моменту, в исходнике есть пример пользовтельских «накончеников» линий. Дуга со стрелочками — весьма приятно выглядит, не правда ли? А делать просто.

Вообще, с GDI+, особенно с TxIPCanvas, многие вещи, о которые раньше только мечталось, становятся приятной повседневностью и рабочими буднями.

Творческих успехов, коллеги!

Виды эллипсов и эллиптических орбит.

Оставить комментарий

Ваш адрес email не будет опубликован. Обязательные поля помечены *