Печать xls(x), doc(x), pdf на указанный принтер

Недавно понадобилось в один свой проект автоматической печати добавить возможность печати xls(x), doc(x) и pdf. Программа в фоне опрашивает указанные ссылки, и если что-то есть, делает скрины страниц и автоматически выводит на указанный принтер. Теперь люди хотят не только скрины.

Поэтому сделал утилитку для закачки и печати указанных форматов. Чтобы заново не вспоминать в следующий раз и не рыть исходники привожу тут листинги. Мало ли кому пригодится. Фишка только в том, что печать происходит на указанный принтер, а не на используемый по умолчанию.

Содержание скрыть

Печать doc(x)

Конечно же используем MSWord в качестве сервера автоматизации.

// печать doc(x)
function PrintWord(const AFileName, APrinter: String): Boolean;
var
  WordApp: OLEVariant;
begin
  Result := FileExists(AFileName);
  if not Result then
  begin
    // возможно, лог
    Exit;
  end;

  WordApp := CreateOleObject('Word.Application');
  try
    // запрет сообщений
    WordApp.DisplayAlerts:= false;
    // открыть документ
    WordApp.Documents.Open(AFileName);

    if not APrinter.IsEmpty then
      // указать используемый принтер
      WordApp.ActivePrinter := APrinter;

    // печать
    WordApp.ActiveDocument.PrintOut()

  finally
    if not VarIsEmpty(WordApp) then
    begin
      WordApp.Quit;
      WordApp := Unassigned;
    end;
  end;
end;

// печать doc(x)

function PrintWord(const AFileName, APrinter: String): Boolean;

var

WordApp: OLEVariant;

begin

Result := FileExists(AFileName);

if not Result then

begin

// возможно, лог

Exit;

end;

WordApp := CreateOleObject('Word.Application');

try

// запрет сообщений

WordApp.DisplayAlerts:= false;

// открыть документ

WordApp.Documents.Open(AFileName);

if not APrinter.IsEmpty then

// указать используемый принтер

WordApp.ActivePrinter := APrinter;

// печать

WordApp.ActiveDocument.PrintOut()

finally

if not VarIsEmpty(WordApp) then

begin

WordApp.Quit;

WordApp := Unassigned;

end;

Указание принтера явно происходит в строке

WordApp.ActivePrinter := APrinter;

1	WordApp.ActivePrinter := APrinter;

Печать xls(x)

Для Excel указание принтера происходит хитрее. В коде нет ошибки, он компилится и прекрасно работает, хоть и подчеркнет, как ошибку. Попробуйте сами.

// печать xls(x)
function PrintExcel(const AFileName, APrinter: String): Boolean;
var
  ExcelApp: OLEVariant;
begin
  Result := FileExists(AFileName);
  if not Result then
  begin
    // возможно, лог
    Exit;
  end;

  ExcelApp := CreateOleObject('Excel.Application');
  try
    // запрет сообщений
    ExcelApp.DisplayAlerts:= false;
    // открыть книгу
    ExcelApp.Workbooks.Open(AFileName);
    // задать ориентацию страниц
    ExcelApp.ActiveSheet.PageSetup.Orientation := xlLandscape;

    if APrinter.IsEmpty then
      // печать на текущий принтер
      ExcelApp.Worksheets.PrintOut()
    else
    begin
      // печать на указанный принтер
      ExcelApp.Worksheets.PrintOut(ActivePrinter:=
        APrinter);
    end;

  finally
    // освободить
    if not VarIsEmpty(ExcelApp) then
    begin
      ExcelApp.Quit;
      ExcelApp := Unassigned;
    end;
  end;
end;

// печать xls(x)

function PrintExcel(const AFileName, APrinter: String): Boolean;

var

ExcelApp: OLEVariant;

begin

Result := FileExists(AFileName);

if not Result then

begin

// возможно, лог

Exit;

end;

ExcelApp := CreateOleObject('Excel.Application');

try

// запрет сообщений

ExcelApp.DisplayAlerts:= false;

// открыть книгу

ExcelApp.Workbooks.Open(AFileName);

// задать ориентацию страниц

ExcelApp.ActiveSheet.PageSetup.Orientation := xlLandscape;

if APrinter.IsEmpty then

// печать на текущий принтер

ExcelApp.Worksheets.PrintOut()

else

begin

// печать на указанный принтер

ExcelApp.Worksheets.PrintOut(ActivePrinter:=

APrinter);

end;

finally

// освободить

if not VarIsEmpty(ExcelApp) then

begin

ExcelApp.Quit;

ExcelApp := Unassigned;

end;

Печать PDF

Если офис установлен повсеместно, то Adobe Reader далеко не всегда. Тяжел, неповоротлив, надоедлив. Поэтому для печати используем SumatraPDF. Утилиту надо скачать и положить рядом с проектом. Установки не требует.

const
// параметры командной строки
// https://www.sumatrapdfreader.org/docs/Command-line-arguments
  SumatraPDF = 'SumatraPDF.exe';

// печать pdf
function PrintPDF(const AFileName, APrinter: String): Boolean;
var
  PrintCommand: String;
begin
  Result := FileExists(AFileName);
  if not Result then
  begin
    // возможно, лог
  end;

  Result := FileExists(SumatraPDF);
  if not Result then
  begin
    // возможно, лог
  end;

  if APrinter.IsEmpty then
    PrintCommand := '-print-to-default'
  else
    PrintCommand := '-print-to "' + APrinter + '"';

  PrintCommand := PrintCommand + ' "'+AFileName+'"';

  Result := ShellExecute (0, 'open', PChar (SumatraPDF),
    PChar(PrintCommand), nil, SW_HIDE)>32;
end;

const

// параметры командной строки

// https://www.sumatrapdfreader.org/docs/Command-line-arguments

SumatraPDF = 'SumatraPDF.exe';

// печать pdf

function PrintPDF(const AFileName, APrinter: String): Boolean;

var

PrintCommand: String;

begin

Result := FileExists(AFileName);

if not Result then

begin

// возможно, лог

end;

Result := FileExists(SumatraPDF);

if not Result then

begin

// возможно, лог

end;

if APrinter.IsEmpty then

PrintCommand := '-print-to-default'

else

PrintCommand := '-print-to "' + APrinter + '"';

PrintCommand := PrintCommand + ' "'+AFileName+'"';

Result := ShellExecute (0, 'open', PChar (SumatraPDF),

PChar(PrintCommand), nil, SW_HIDE)>32;

end;

Возможно, потребуется более гибкая настройка вывода на принтер. Для этих целей используем параметры командной строки.

Использование

Предположим, что это не консольное приложение, т.к. окна пользователю показывать не хотим. Все происходит автоматически и в фоновом режиме. Но между тем, предполагается запуск из командной строки, где первым параметром указан файл, вторым — принтер.

program off_print;
{$APPTYPE GUI}

uses
  Windows,
  Classes,
  SysUtils,
  ShellApi,
  StrUtils,
  ComObj,
  Variants,
  {$IF CompilerVersion >= 23}
  Vcl.Printers,
  {$ELSE}
  Printers,
  {$IFEND}
  Excel2000;

//...

// попытка найти принтер в списке
function IndexOfStrings(AList: TStrings; const AValue: String): Integer;
var
  i: Integer;
  s, v: String;
begin
  v := ReplaceStr(AnsiLowerCase(AValue),' ','');
  for i := 0 to AList.Count-1 do
  begin
    s := ReplaceStr(AnsiLowerCase(AList[i]),' ','');
    if AnsiCompareStr(s,v) = 0 then
    begin
      Result := i;
      Exit;
    end;
  end;

  Result := -1;
end;

var
  PrinterIndex: Integer;
  PrinterName: String;
  FileName: String;
  FileExt: String;

begin
  FileName := ParamStr(1);
  PrinterName := ParamStr(2);

  if FileName = '/plist' then
  begin
    MessageBox(0,PChar(Printer.Printers.Text),'Printers',MB_OK);
    Exit;
  end;

  FileExt := AnsiLowerCase(ExtractFileExt(FileName));
  FileName := ExpandFileName(FileName);

  PrinterIndex := IndexOfStrings(Printer.Printers, PrinterName);
  if PrinterIndex < 0 then
    PrinterName := ''
  else
    PrinterName := Printer.Printers[PrinterIndex];

  if pos ('.xls',FileExt) > 0 then
    PrintExcel(FileName, PrinterName)
  else
  if pos ('.doc',FileExt) > 0 then
    PrintWord(FileName, PrinterName)
  else
  if pos ('.pdf',FileExt) > 0 then
    PrintPDF(FileName, PrinterName)
  ;

end.

program off_print;

{$APPTYPE GUI}

uses

Windows,

Classes,

SysUtils,

ShellApi,

StrUtils,

ComObj,

Variants,

{$IF CompilerVersion >= 23}

Vcl.Printers,

{$ELSE}

Printers,

{$IFEND}

Excel2000;

//...

// попытка найти принтер в списке

function IndexOfStrings(AList: TStrings; const AValue: String): Integer;

var

i: Integer;

s, v: String;

begin

v := ReplaceStr(AnsiLowerCase(AValue),' ','');

for i := 0 to AList.Count-1 do

begin

s := ReplaceStr(AnsiLowerCase(AList[i]),' ','');

if AnsiCompareStr(s,v) = 0 then

begin

Result := i;

Exit;

end;

Result := -1;

end;

var

PrinterIndex: Integer;

PrinterName: String;

FileName: String;

FileExt: String;

begin

FileName := ParamStr(1);

PrinterName := ParamStr(2);

if FileName = '/plist' then

begin

MessageBox(0,PChar(Printer.Printers.Text),'Printers',MB_OK);

Exit;

end;

FileExt := AnsiLowerCase(ExtractFileExt(FileName));

FileName := ExpandFileName(FileName);

PrinterIndex := IndexOfStrings(Printer.Printers, PrinterName);

if PrinterIndex < 0 then

PrinterName := ''

else

PrinterName := Printer.Printers[PrinterIndex];

if pos ('.xls',FileExt) > 0 then

PrintExcel(FileName, PrinterName)

else

if pos ('.doc',FileExt) > 0 then

PrintWord(FileName, PrinterName)

else

if pos ('.pdf',FileExt) > 0 then

PrintPDF(FileName, PrinterName)

;

end.

Друзья, спасибо за внимание!

Подписывайтесь на телегу.

Может быть знаете еще простые способы печати? Поделитесь в комментариях )

5 2 голоса

Рейтинг статьи

0 комментариев

Межтекстовые Отзывы

Посмотреть все комментарии